/PERM OUTPUT
 .LOC 17000
    .SIZE
    .SIXBT 'X'
    300002                  /OUTPUT
    .SIXBT 'N'
XO
    SNL; JMP X1             /CLOSE ->
    SAD .NL; JMP* XO        /NL ->
    JMS* XO-1               /SEND CHAR
    JMP* XO
X1  JMS* XO-1               /TRANSMIT CLOSE SIGNAL
    LAC 10; DAC G+5         /STORE NEST POINTER
    AND (60000; TAD (C      /FULL 15-BIT AD
    DAC DV+3; DAC I         /FOR TRANSFER START
    LAC XO; DAC G+7         /RESUMPTION AD
    JMS GEN                 /STACK INITIAL ORDERS
G   LAC C+5; DAC* C+6       /TO RESTORE NP
    STL; NOP                /AND RESUME
    JMP* C+7                /AFTER CALL OF XO
    -1; 10
    -1
    0                       /(ENDMARK)
    XCT 21                  /HLT?
X2  LAC (14000; DAC DV      /FUNCTION + UNIT (0)
    LAC (DV
    GUARD; JMP .DH          /CALL HANDLER
    GUARD                   /WAIT FOR TRANSFER
    LAC DV; SMA!SZA; WAIT
    ION
    SMA!CMA; JMP X3         /OK ->
    GUARD; JMP .MH          /REPORT
    JMP X2
X3  LAC X4; DAC XO+1        /NO RE-ENTRY
    CLL!CLC
X4  JMP* XO
GEN
G1  LAC I; CMA; TAD 10      /ENOUGH ROOM?
    SPA; XX                 /HLT IF NOT
    LAC* GEN; ISZ GEN       /END OF SEQUENCE?
    SNA; JMP* GEN           /YES =>
    DAC* I; ISZ I           /STORE VALUE
    JMP G1
I
DV  14000; 40; -20000+C; 0
C=3400
GUARD=JMS 3;WAIT=JMP 2
.DH=16000;.MH=16010;.NL=16020
    .END