''HEAD, 6502 OUTPUT CONVERSION
     // EDIT DATE   10OCT78  12:51
     // SOURCE FILE ENTERAJH.LO
     // AUTHOR      A. J. HOWARD
''USE, PACKET AJH.US; 1
     'TP' [0]:'LBR'
        BUFFER,
        'RBR'
     'DP' BUFFERX,
     'DP' DP VALUE,
     COUNT,
     MINUS FLAG,
     SP VALUE,
 ;;  .....
 ;
     HEX TAB [16] = "0123456789ABCDEF",
 ;ENTER SP:: 'LBR'           // (PKT, VAL, WIDTH)
     [FL1] -> DP VALUE,
     ENTER DP VALUE,
     'RBR'
  ENTER DP:: 'LBR'           // (PKT, VAL, WIDTH)
     'DP' [FL1] -> DP VALUE,
     ENTER DP VALUE,
     'RBR'
  ENTER DP VALUE:'LBR'
     [FL2] -> COUNT,
     SETUP CONVERT,
     0 -> MINUS FLAG,
     DP VALUE < 0:
        -DP VALUE -> DP VALUE,
        ^MINUS FLAG;;
     'DO'
        DP VALUE/10 -> DP VALUE,
        REMAINDER + "0" -> BUFFER [BUFFERX],
        'WHILE' 'DEC' COUNT # 0:
           'DEC' BUFFERX,
           'END'
     COUNT # 0 & MINUS FLAG # 0:
        "-" -> BUFFER [BUFFERX];;
     'RBR'
  ENTER HX:: 'LBR'           // (PKT, VAL, WIDTH)
     [FL2] -> COUNT,
     SETUP CONVERT,
     [FL1] -> SP VALUE,
     'DO'
        HEX TAB [SP VALUE & 0F] -> BUFFER [BUFFERX],
        'WHILE' 'DEC' COUNT # 0:
           SP VALUE 'RS' 4 -> SPVALUE,
           'DEC' BUFFERX,
           'END'
     'RBR'
  SETUP CONVERT:'LBR'
     COUNT + CHARX [FL0] -> CHARX [FL0] > MAX CHARX [FL0]:
        CHARX [FL0] -> MAX CHARX [FL0];;
     BUFAD [FL0] + CHARX [FL0] - 1 -> BUFFERX,
     'RBR'
     .....
     'DP' STRINGX,
 ;
 ;ENTER ST:: 'LBR'           // (PKT, STRING, WIDTH)
     [FL2] -> COUNT,
     SETUP CONVERT,
     FL1 + COUNT - 1 -> STRINGX,
     'DO'
        [STRINGX] -> BUFFER [BUFFERX],
        'WHILE' 'DEC' COUNT # 0:
           'DEC' STRINGX,
           'DEC' BUFFERX,
           'END'
     'RBR'
  ENTER BL:: 'LBR'           // (PKT, WIDTH)
     [FL1] -> COUNT,
     SETUP CONVERT,
     CLEAR BUFFER,
     'RBR'
  CLEAR BUFFER:'LBR'
     'DO'
        " " -> BUFFER [BUFFERX],
        'WHILE' 'DEC' COUNT # 0:
           'DEC' BUFFERX,
           'END'
     'RBR'
     .....
 ;
 ;ENTER TA:: 'LBR'           // (PKT, COL)
     0 -> CHARX [FL0],
     [FL1] -> COUNT,
     SETUP CONVERT,
     'RBR'
  ENTER PC:: 'LBR'           // (PKT, RIGHT MOVE)
     [FL1] -> COUNT,
     SETUP CONVERT,
     'RBR'
  ENTER MC:: 'LBR'           // (PKT, LEFT MOVE)
     - [FL1] -> COUNT,
     SETUP CONVERT,
     'RBR'
     .....
 ;
 ;ENTER EJ:: 'LBR'           // (PKT)
     255 -> DRIVER FLAG [FL0],
     CALL DRIVER,
     'RBR'
  ENTER LN:: 'LBR'           // (PKT, LINES)
     [FL1] -> DRIVER FLAG [FL0],
     CALL DRIVER,
     'RBR'
  CALL DRIVER:'LBR'
     [DRIVER [FL0]],
     MAX CHARX [FL0] -> COUNT - 1 + BUFAD [FL0] -> BUFFERX,
     CLEAR BUFFER,
     1 -> CHARX [FL0] -> MAX CHARX [FL0],
     'RBR'
     .....
''END