! Program to inform you which EMAS it is running on, (2900 range).

%EXTERNAL %ROUTINE WHICHEMAS (%STRING(255) PARM)
%RECORDFORMAT COMF(%INTEGER OCPTYPE,IPLDEV,SBLKS,SEPGS,NDISCS,  %C
         DDTADDR,GPCTABSIZE,GPCA,SFCTABSIZE,SFCA,SFCK,DIRSITE,  %C
         DCODEDA,SUPLVN,TOJDAY,DATE0,DATE1,DATE2,  %C
         TIME0,TIME1,TIME2,EPAGESIZE,USERS,CATTAD,DQADDR,  %C
         %BYTEINTEGER NSACS,RESV1,SACPORT1,SACPORT0, %C
         NOCPS,RESV2,OCPPORT1,OCPPORT0, %C
         %INTEGER ITINT,CONTYPEA,GPCCONFA,FPCCONFA,SFCCONFA, %C
         BLKADDR,RATION,SMACS,TRANS,%LONGINTEGER KMON,  %C
         %INTEGER DITADDR,SMACPOS,SUPVSN,PSTVA,SECSFRMN,SECSTOCD, %C
         SYNC1DEST,SYNC2DEST,ASYNCDEST,MAXPROCS,INSPERSEC,ELAPHEAD, %C
         COMMSRECA,STOREAAD,PROCAAD,SFCCTAD,DRUMTAD,TSLICE,SP0,SP1, %C
         SP2,SP3,SP4,SP5,SP6,SP7,SP8, %C
         LSTL,LSTB,PSTL,PSTB,HKEYS,HOOT,SIM,CLKX,CLKY,CLKZ,  %C
         HBIT,SLAVEOFF,INHSSR,SDR1,SDR2,SDR3,  %C
         SDR4,SESR,HOFFBIT,S2,S3,S4,END)
%CONSTSTRING (4) %ARRAY OCPTYPE(1 : 6) =  "2950","2960","2970",
     "2988","2972","2976"
%RECORD (COMF) %NAME R

   R == RECORD(X'80000000'+48<<18)
   PRINTSTRING("You are on a ")
   PRINT STRING ("dual ") %IF R_NOCPS#1
   PRINT STRING (OCPTYPE(R_OCPTYPE))
   PRINT STRING (" with")
   WRITE(R_SBLKS*128,1)
   PRINTSTRING(" Kbytes of store")
   NEWLINE
%END

%ENDOFFILE