%EXTERNALROUTINE PMONENABLE(%STRING(63) S)
%EXTERNALINTEGERFNSPEC DMONENABLE(%STRING(11) FILE,%INTEGER KB)
%STRING(11) FILE
%INTEGER KB
  S->FILE.(",").S
  KB=0
  %UNTIL S="" %THEN KB=10*KB+CHARNO(S,1)-'0' %AND %C
    S->(FROMSTRING(S,1,1)).S
  WRITE(DMONENABLE(FILE,KB),1)
%END
!-----------------------------------------------------------------------
%EXTERNALROUTINE PMONDISABLE(%STRING(255) S)
%EXTERNALROUTINESPEC DMONDISABLE
  DMONDISABLE
%END
!-----------------------------------------------------------------------
%EXTERNALROUTINE PMONON(%STRING(255) S)
%EXTERNALROUTINESPEC DMONON
  DMONON
%END
!-----------------------------------------------------------------------
%EXTERNALROUTINE PMONOFF(%STRING(255) S)
%EXTERNALROUTINESPEC DMONOFF
  DMONOFF
%END
!-----------------------------------------------------------------------
%EXTERNALROUTINE PMONTEXT(%STRING(255) S)
%EXTERNALROUTINESPEC DMONTEXT(%STRING(23) S)
%INTEGER I,J
  S=S."
"
  I=1
  %CYCLE
    J=I+22
    %IF LENGTH(S)<J %THEN J=LENGTH(S)
    DMONTEXT(FROMSTRING(S,I,J))
    %IF J=LENGTH(S) %THEN %RETURN %ELSE I=J+1
  %REPEAT
%END
!-----------------------------------------------------------------------
%EXTERNALROUTINE PMONDECYCLE(%STRING(63) S) 
%EXTERNALROUTINESPEC DEFINE(%STRING(63) S) 
%SYSTEMROUTINESPEC CONNECT(%STRING(31) FILE,%INTEGER MODE,HOLE,PROT, %C
  %RECORDNAME R,%INTEGERNAME FLAG)
%SYSTEMROUTINESPEC DISCONNECT(%STRING(31) FILE,%INTEGERNAME FLAG)
%RECORDFORMAT RF(%INTEGER CONAD,I,J,K)
%RECORD R(RF)
%RECORDFORMAT HEADERF(%INTEGER CURP,DATA,MAX,H4,H5,H6,CYCP,H8)
%RECORDNAME HEADER(HEADERF)
%STRING(63) F1,F2
%INTEGER FLAG,BASE,I,J,K,L
  S->F1.(",").F2
  CONNECT(F1,0,0,0,R,FLAG)
  BASE=R_CONAD
  HEADER==RECORD(BASE)
  DEFINE("STREAM01,".F2)
  SELECT OUTPUT(1)
  I=HEADER_CYCP
  %UNLESS I>=HEADER_DATA %THEN %START
    SELECT OUTPUT(0)
    PRINT STRING("FILE NOT CYCLIC")
    %RETURN
  %FINISH
  %IF I=0 %THEN PRINT STRING("HEADER NOT FILLED IN") %AND %RETURN
  %IF BYTE INTEGER(BASE+I)=0 %THEN I=HEADER_DATA %C
    %ELSE PRINT STRING("FILE CYCLED")
  %UNTIL I=HEADER_CYCP %CYCLE
    PRINT SYMBOL(BYTE INTEGER(BASE+I))
    I=I+1
    %IF I=HEADER_CURP %THEN I=HEADER_DATA
  %REPEAT
  DISCONNECT(F1,FLAG)
%END
!-----------------------------------------------------------------------
%ENDOFFILE