%constinteger max base commands=12
%conststring(255)%array base commands(1:max base commands)=%C
"alias","remove","monitor","stop","quit","launch","broadcast","tell",
"autoattack","surrender","dump","resources"
!"B","C","D","E","F","G","H","I","J","K","AL","LI","RE","ST"
%recordformat com form (%string(80)comstr,%byteinteger base,type)
%constinteger max possible commands=20
%ownrecord(com form)%array commands(1:max possible commands)
%owninteger max commands=0

%routine sort(%record(com form)%arrayname r,%integer lo,hi)
!%routine sort(%stringarrayname r,%integer lo,hi)
%integer i,j,k,l,n
%record(com form)x
!%string(255)x
l=lo-1
n=hi
!%while n<hi-l %cycle
!  n=2*n
!%repeat
! <=> 1<<((32- shz{shift while not zero}(hi-l-1))&31)
!n contains smallest +ve integral power of 2 not less that hi-lo+1
*lss_n;*isb_l;*isb_1;*shz_%tos;*lb_32;*sbb_%tos;*lss_1;*rot_%b;*st_n
%cycle
 n=n//2
 %returnif n=0
 i=l
 %cycle
  i=i+1
  j=i+n
  %exitif j>hi
  k=i
  %while r(j)_comstr<r(k)_comstr %cycle
!  %while r(j)<r(k) %cycle
   x=r(j)
   r(j)=r(k)
   r(k)=x
   j=k
   k=k-n
   %exitif k<lo
  %repeat
 %repeat
%repeat
%end


%integerfn search(%record(com form)%arrayname tab,%integer lo,hi,%string(255)wanted)
!%integerfn search(%stringarrayname tab,%integer lo,hi,%string(255)wanted)
%integer pos
hi=hi+1
lo=lo-1
%while hi-lo-1>0 %cycle
  pos=(lo+hi)//2
  %result=pos %if tab(pos)_comstr=wanted
!  %result=pos %if tab(pos)=wanted
  %if tab(pos)_comstr<wanted %then lo=pos %else hi=pos
!%if tab(pos)<wanted %then lo=pos %else hi=pos
%repeat
%result=0
%end

%routine initialise commands
%integer i
%for i=1,1,max base commands %cycle
  commands(i)_comstr=base commands(i)
  commands(i)_base=i
  commands(i)_type=1
%repeat
max commands=max base commands
sort(commands,1,max commands)
%end

%routine add alias(%string(80)com,al)
%integer i,j
i=search(commands,1,max commands,com)
%if i=0 %then printstring("original com not found")%and newline %andreturn
j=search(commands,1,max commands,al )
%if j=0 %and max commands=max possible commands %start
   printstring("no room for alias")
   newline
   %return
%finish
%if j=0 %start
   max commands=max commands+1
   j=max commands
%finishelsestart
   %if commands(j)_type=1 %start
      printstring("cannot overwrite base command")
      newline
      %return
   %finish
%finish
commands(j)_comstr=al
commands(j)_base=commands(i)_base
commands(j)_type=2
sort(commands,1,max commands)
%end

%routine remove alias(%string(80)al)
%integer i
i=search(commands,1,max commands,al)
%if i=0 %start
   printstring("alias not found")
   newline
   %return
%finish
%if commands(i)_type#2 %start
   printstring("this was not an alias")
   newline
   %return
%finish
commands(i)_base=0
commands(i)_type=0
commands(i)_comstr="".tostring(127)
length(commands(i)_comstr)=80
sort(commands,1,max commands)
max commands=max commands-1
%end

%integerfn get com no(%string(80)s)
%integer i
i=search(commands,1,max commands,s)
%result=0 %if i=0
%result=commands(i)_base
%end

%externalroutine zz(%string(255)dummy)
%string(255)s,c,al
%integer i
initialise commands
!%for i=1,1,max commands %cycle
!   readstring(commands(i))
!%repeat
!printstring("Commands now read in")
!newline
!sort(commands,1,max commands)
!%for i=1,1, max commands %cycle
!  printstring(commands(i))
!  newline
!%repeat
%cycle
   readstring(s)
i=get com no(s)
!   i=search(base commands,1,max base commands,s)
   %if i>0 %start
         printstring(s." is command number ")
         write(i,1)
   %finishelse printstring(s." not known")
  newline
%if i=1 %start{alias}
  readstring(c);readstring(al)
  add alias(c,al)
%finish
%if i=2 %start{remove}
  readstring(al)
  remove alias(al)
%finish
%if i=3 %start{list}
  %for i=1,1,max commands %cycle
     write(i,3)
     printstring("   ".commands(i)_comstr)
     write(commands(i)_base,5)
     write(commands(i)_type,5)
     newline
   %repeat
%finish
%if i=4 %thenreturn
%repeat
%end
%endoffile