EXTERNALROUTINE  LASTLOGS(STRING (255)S)
!
!
EXTERNALROUTINESPEC  PROMPT(STRING (255)S)
EXTERNALROUTINESPEC  RSTRG(STRINGNAME  S)
EXTERNALROUTINESPEC  GETAVFSYS(INTEGERNAME  N,INTEGERARRAYNAME  A)
EXTERNALINTEGERFNSPEC  GETUSNAMES(INTEGERNAME  N,INTEGER  ADR,FSYS)
EXTERNALINTEGERFNSPEC  DSFI(STRING (6)U,INTEGER  F,T,S,A)
!
!
INTEGER  L, AL, NSYS, F, ADR, NU, J, K, C0, C1, N
STRING (15)U0
INTEGERARRAY  A(0:99)
STRINGNAME  U1
BYTEINTEGERARRAY  UNAMES(0:2400)
!
         PROMPT("USERS: ")
         RSTRG(U0)
!
         N = 0; ! GOOD NAMES
         AL = ADDR(L)
         ADR = ADDR(UNAMES(0))
         GET AV FSYS(NSYS, A)
!
         CYCLE  F = 0, 1, NSYS-1
            J = GETUSNAMES(NU, ADR, A(F))
            IF  NU > 0 START 
               CYCLE  J = 0, 7, (NU-1)*7
                  U1 == STRING(ADR+J)
                  CYCLE  K = 1, 1, 6
                     C0 = BYTEINTEGER(ADDR(U0)+K)
                     C1 = BYTEINTEGER(ADDR(U1)+K)
                     UNLESS  C0=M'?' OR  C0=C1 C 
                     THEN  -> NO GO
                  REPEAT 
!
                  K = DSFI(U1, A(F), 6, 0, AL)
                  IF  K = 0 START 
   IF  L >> 17 = 0 START 
      PRINTSTRING(U1)
      WRITE(L&31,1)
      WRITE((L>>5)&15,1)
      WRITE((L>>9)+70,1)
      NEWLINE
      L = L << 17
      K = DSFI(U1, A(F), 16, 1, AL)
   FINISH 
                  FINISH 
   UNLESS  K = 0 START 
      PRINTSTRING("DSFI ".U1." FSYS")
      WRITE(A(F), 1)
      WRITE(K, 1)
      NEWLINE
   FINISH 
NO GO:
               REPEAT 
            FINISH 
         REPEAT 
!
END 
ENDOFFILE