!TITLE APPENDIX A: IMP80 Syntax
!KEY
<letter>      ::=  A | B | C | D | E | F | G | H | I | J | K | L | M |
                   N | O | P | Q | R | S | T | U | V | W | X | Y | Z |
                   a | b | c | d | e | f | g | h | i | j | k | l | m |
                   n | o | p | q | r | s | t | u | v | w | x | y | z

<digit>       ::=  0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9

<newline>     ::=  {newline character}

<bar>         ::=  {| character}

<character>   ::=  ! | " | # | $ | % | & | ' | ( | ) | * | + | , | - |
                   . | / | : | < | = | > | ? | @ | [ | ] | \ | ^ | _ |
                   ` | ~ | ; | <letter> | <digit> | <bar>

<text>        ::=  [<character>]...

<comment>     ::=  %comment <text> <newline> | ! <text> <newline>

<integer>     ::=  <digit> [<digit>]...
!PAGE
<letdig>      ::=  <letter> | <digit>

<name>        ::=  <letter> [<letdig>]...

<namelist>    ::=  <name> [, <name>]...

<int const>   ::=  [<plus>] <integer>

<frac>        ::=  . [<integer>]

<dec const>   ::=  [<int const>] [<frac>] [@ <int const>]

<base const>  ::=  <int const> _ <letdig>... | <letter> ' <letdig>... '

<charnl>      ::=  <character> | <newline>

<char const>  ::=  ' <charnl> ' | M' <charnl>... '

<str const>   ::=  " [<charnl>]... "

!PAGE
<const>       ::=  <int const> | <dec const> | <base const> |
                   <char const> | <str const>

<unop>        ::=  + | - | \ | ~

<assop>       ::=  = | == | <- | ->

<plus>        ::=  + | -

<comp1>       ::=  <comp2> | -> | == | \== | ##

<comp2>       ::=  = | # |  \= | <> | > | >= | < | <=

<op>          ::=  * | / | // | + | - | ** | **** | \ | \\ | >> | << |
                   ! | !! | & | .

<app>         ::=  ( <expr> [, <expr>]... )

<recel>       ::=  _ <name> [<app>]

!PAGE
<operand>     ::=  <name> [<app>] [<recel>]... | <const> | ( <expr> )

<expr>        ::=  [<unop>] <operand> [<op> <operand>]... 

<count>       ::=  ( <expr> ) | (*)

<exprcount>   ::=  <expr> [<count>]

<constlist>   ::=  = <exprcount> [, <exprcount>]...

<decln>       ::=  [[%array] %name] <namelist> |
                   %array [%format] <adecln> 

<adecln>      ::=  <namelist> <bpair> [, <namelist> <bpair>]...

<rfelmnt>     ::=  [[%array] %name] <namelist> | %array <adecln> 

<rfdeclistor> ::=  ( <rfdeclist> [%or <rfdeclist>]... )

<rfdeclist>   ::=  <rfdec> [, <rfdec>]...
!PAGE
<rfdec>       ::=  <xtype> <rfelmnt> | <rfdeclistor>

<rfref>       ::=  ( <name> ) | <rfdeclistor>

<btype>       ::=  %integer | %real | %long %real

<type>        ::=  %integer | %real | %long <btype> | %byte [%integer] |
                   %short [%integer] | %half [%integer] | %string<count>

<xtype>       ::=  <type> | %record <rfref>

<oname>       ::=  <name> [%alias " <text> "]

<onamelist>   ::=  <oname> [, <oname>]...

<ownlist>     ::=  <onamelist> [= <expr>]

<owndec>      ::=  [[%array] %name] [%spec] <ownlist> [, <ownlist>]... |
                   %array [%format] [%spec] <oname> <bpair>[<constlist>]

!PAGE
<fm>          ::=  %fn | %function | %map

<rt>          ::=  %routine | <type> <fm> 

<fpdel>       ::=  <xtype> [[%array] %name] <namelist> |
                   <rt> [%name] <namelist> [<fpp>] |
                   %name <namelist> 

<fpp>         ::=  ( <fpdel> [, <fpdel>]... )

<range>       ::=  <expr> : <expr>

<bpair>       ::=  ( <range> [, <range>]... )

<xown>        ::=  %own | %external | %constant | %const

<%sed>        ::=  %system | %external | %dynamic

<endlist>     ::=  %of %program | %of %file | %of %list

!PAGE
<restofcond>  ::=  [%and <sc>]... | [%or <sc>]...

<sc>          ::=  <expr> <comp1> <expr> [<comp2> <expr>] |
                   ( <sc> <restofcond> ) |
                   %not <sc> 

<restofcond>  ::=  [%and <sc>]... | [%or <sc>]...

<%wf>         ::=  %while <sc> <restofcond> | 
                   %for <name> = <expr> , <expr> , <expr>

<%iu>         ::=  %if | %unless

!PAGE
<ui>          ::=  <name> [<app>] [<recel>]...
                       [<assop> <expr>] [%and <ui>] |
                   -> <name> [<app>] |
                   %return |
                   %result <assop> <expr> | 
                   %monitor [%and <ui>] |
                   %stop |
                   %signal [%event] <const> [, <expr>] |
                   %exit |
                   %continue

<ci>          ::=  <%iu> <sc> <restofcond> <restofiu>

<restofiu>    ::=  [%then] %start | %then <ui> [<else>]

<else>        ::=  %else %start |
                   %else <ci> |
                   %else <ui>

!PAGE
<restofss>    ::=  <%iu> <sc> <restofcond> |
                   %until <sc> <restofcond> |
                   <%wf>

<s>           ::=  ; | <newline>

<program>     ::=  <ss>...
!PAGE
<ss>          ::=  %begin <s> |
                   <xtype> <decln> <s> |
                   %record %format <name> <rfdeclistor> <s> |
                   [<%sed>] <rt> [%spec] <name> [<fpp>] <s> |
                   <xown> <xtype> <owndec> <s> |
                   %include " <text> " |
                   %switch <namelist> <bpair>
                       [, <namelist> <spair>]... <s> |
                   %on [%event] [, <integer>]... %start <s> |
                   <ui> [<restofss>] <s> |
                   <ci> <s> |
                   %finish [<else>] <s> |
                   [<%wf>] %cycle <s> |
                   %repeat [%until <sc> <restofcond>] <s> | 
                   <name> [<app>] : |
                   <name> (*) : |
                   %list <s> |
                   %end [<endlist>] <s> | 
                   <comment> |
                   <s> 
!STOP
!<Notes
!KEY

* In the above syntax, items in italics are non-terminals, '|' separates
  alternatives, '::=' means 'is defined as', items enclosed in [..]
  brackets are optional, and items followed by '...' can be repeated one
  or more times.  All other characters stand for themselves, except that
  {...} indicates a "descriptive" definition, involving a newline
  character or a character used in the statement of the syntax itself.

* The case of letters is ignored in IMP80 programs except within
  character constants.

* Space characters are only significant within character constants or
  following a keyword (%real, %if, %unless, %end, %not, etc.).

* <type> definition: not all the types may be available in some
  implementations.

* {EMAS IMP80: <type> definition: <count> replaced by [<count>]}

* {IMP77: <op> definition: ** | **** replaced by ^ | ^^ . }
!PAGE
* Text preceded by '{', terminated by '}' and appearing between
  syntactic elements of a program is treated as a comment.  Such a
  comment is also terminated by a newline character.

* IMP80 statements can be continued on the next line with %c.  The %c is
  not required if the break comes immediately after a comma.
  {IMP77: comment statements cannot be continued.}
!>