@echo off
set dolink=yes
set docode=no

:parseargs
if "%1"=="" goto help
if "%1"=="/?" goto help
if "%1"=="/h" goto help
if "%1"=="/H" goto help
if "%1"=="-h" goto help
if "%1"=="-H" goto help
if "%1"=="/c" goto setlink
if "%1"=="-c" goto setlink
if "%1"=="/Fc" goto setcode
if "%1"=="-Fc" goto setcode
rem here it must be a filename
goto compile
:setlink
set dolink=no
shift
goto parseargs
:setcode
set docode=yes
shift
goto parseargs

:compile
if not exist %1.imp goto nosource

rem set up our files

set codefile=NUL
if "%docode%"=="yes" set codefile=%1.cod

pass1 %1.imp,c:\imp\stdperm.imp/%1.icd:b,%1.lst
if errorlevel 1 goto end

pass2 %1.icd:b,%1.imp/%1.ibj,%codefile%
del %1.icd
pass3 %1.ibj %1.obj
del %1.ibj

if "%dolink%"=="no" goto end
link /nologo /stack:40000 %1.obj,;
del %1.obj
goto end

:nosource
echo Source file not found?

:help
echo Usage: I77 [-c] [-Fc] basename
echo where basename is the source file (without .IMP extension)
echo       -c       inhibits the link phase
echo       -Fc      produces a .COD file with source and assembler output

:end