%begin
   %conststring(*) PvsFile = "$.3l.pvs.pvsbin"
   %include "pvsinc"
   %externalstring(255)%fnspec CliParam %alias "3L_IMP_CLI_PARAM"
   %string(255) P = CliParam
   %integer N, J
   %return %if P = ""
   %if Charno(P, 1) = '#' %start
      Charno(P, 1) = ' '
      N = StoI(P)
   %else
      N = 0
      %for J = 1, 1, Max Test %cycle
         %if Test Id(J) = P %start
            N = J;  %exit
         %finish
      %repeat
      %if N = 0 %start
         Printstring("Cannot locate ".P)
         Newline
         %return
      %finish
   %finish
   %unless 1 <= N <= Max Test %start
      Printstring("spurious test number #");  Write(N, 0);  Newline
      %return
   %finish
   %begin
      %integer S, F, T, Base, Size
      F = Test  Start(N)
      T = Test Finish(N)
      Open Output(1, "pas.test");  Select Output(1)
      %externalroutinespec Pos Input %alias "3L_IMP_POSITION_INPUT"(%integer N)
      Open Binary Input(1, PvsFile)
      Select Input(1)
      Pos Input(F)
  !    skipsymbol %for S = 1, 1, F-1
      %while F <= T %cycle
         Readsymbol(S)
         Printsymbol(S)
         F = F+1
      %repeat
   %end
%endofprogram