!
! COMMON.IMP
!
! GATT fault reporting and general service routines.
! This is the implementation for the PANOS operating system on the BBC.
!
! Rev  0 25-FEB-85 ADC    cloned from JHD's BBC Tiny Kernel implementation
! Rev  1 28-FEB-85 ADC    Changed Fatal Error to do Stop() rather than %STOP
!

%external %string(31) %spec Version, Release, Revision, Product Code, Fname

%external %routine Fatal Error ( %string(255) S )
   %externalroutinespec exit %alias "3L___exit"(%integer N)
   %if S # "" %start
      Select Output(0)
      Print String(Fname." fails -- ".S)
      New Line
   %finish
   Exit(1)
%end

%external %routine CSR %alias "3L_CSR" ( %string(63) S )
   Fatal Error("program failure in module ".S.", please submit a CSR")
%end

%external %routine Warning Message ( %string(255) S )
   %integer Old = Output Stream
   Select Output(0)
   Print String(Fname.": ".S)
   New Line
   Select Output(Old)
%end

%external %string(63) %function Version String %alias "3L_VERSION_STRING"
   %string(63) R = Version . "." . Release
   R = R . "." . Revision %unless Revision = "0"
   %result = R
%end

%external %routine Print Version Number
   Print String(Fname." version ".Version String)
%end

%external %routine Print Identification
   %if Product Code # Fname %start
      Print String("Product:")
      Print String(Product Code)
      Print String(", Version:")
   %finish
   Print Version Number
   New Line
%end