*0

I0,0
J,0
X,0
Y,0
Z0,0
N,0
CHORD,0
K1,1600
K,0
KA,0
KB,0
KC,0
KD,0
KE,0
KF,0
KG,0
U1,0
U2,0
U3,0
U4,0
V1,0
V2,0
V3,0
V4,0
W1,0
W2,0
W3,0
W4,0
CLCK,6114
MSGE,MSGE1
RSYM,RSYM1
PSMBL,PSMBL1
MULT,MULT1
DIVIDE,DIV1
NOTE,NOTE1
KEY,KA
LENGTH,LNGTH1
F,1500
LNGTH1,0
40
10
1
0
0
0
0
0
0
0
0
20
0
0
0
4
0
2
0
0
0
0
0
0
0
LT0I,LT0
LT41I,LT41
LT31I,LT31
LT21I,LT21
L28I,L28
L4I,L4
L5I,L5
L14I,L14
LA4I,LA4
LA5I,LA5
L0I,L0
L15I,L15
L18I,L18
L19I,L19
L26I,L26
L29I,L29
L1I,L1
L16I,L16
NOTE1,30
32
33
35
37
40
42
N480,0740
DFDGE4,ISZ U4
DFDGE3,ISZ U3
DFDGE2,ISZ U2
FDGE,DCA I0
ZP1,7645
A,7677
SHRP,7735
FLT,7737
DOLR,7734
SLSH,7721
LNFD,7766
SCLN,7705
GP1,7670
NTRL,7736
V,7652
NM61,
EQLS,7703
NM4,7714
NM3,7715
NM2,7716
FSTP,7722
T,7654
N9P1,7706
N0,7720
R,7656
PLUS,7725
MINUS,7723
NM12,7764
NM13,
CR,7763
NUM,2500
MAX,0077
B177,0177
SP,7740
RBT,7601
CLICK,6114
CLOCK,6112
LBKT,7730
RBKT,7727
S,7647




































































*200

6044
JMS I MSGE
215
212
315  /M
325  /U
323  /S
311  /I
303  /C
240
303  /C
317  /O
315  /M
320  /P
311  /I
314  /L
305  /E
322  /R
257  //
262  /2
215
212
0
L0,LAS
RAL
SZL
JMP I LT0I
RTR
SNL
JMP L0
CLA
TAD N480
DCA Y
DCA KA
DCA KB
DCA KC
DCA KD
DCA KE
DCA KF
DCA KG
TAD K1
DCA K
TAD DFDGE4
DCA I LT41I
TAD DFDGE3
DCA I LT31I
TAD DFDGE2
DCA I LT21I
DCA CHORD
RFC
L1,JMS I RSYM
TAD I0
TAD ZP1
SMA CLA
JMP LA1
TAD I0
TAD A
SMA CLA
JMP L2
LA1,TAD I0
TAD SHRP
SNA CLA
JMP L3
TAD I0
TAD FLT
SNA CLA
JMP L3
TAD I0
TAD DOLR
SNA CLA
JMP I L4I
TAD I0
TAD SLSH
SZA
JMP L1
L5,JMS I RSYM
L15,CLA
TAD I0
TAD LNFD
SNA CLA
JMP L1
TAD I0
TAD SCLN
SNA
JMP L1
JMP L5
L3,DCA KA
DCA KB
DCA KC
DCA KD
DCA KE
DCA KF
DCA KG
TAD I0
DCA J
L6,JMS I RSYM
TAD I0
TAD LNFD
SNA CLA
JMP L1
TAD I0
TAD SCLN
SNA CLA
JMP L1
TAD I0
TAD GP1
SMA CLA
JMP L6
TAD I0
TAD A
SPA
JMP L6
TAD KEY
DCA I0
TAD J
TAD NTRL
DCA I I0
JMP L6
L2,TAD I0
TAD S
SZA CLA
JMP LA13
DCA I K
CMA
DCA I K
JMP L5
NOP
LA13,NOP












































































*400

TAD I0
TAD V
SZA
JMP L7
L8,JMS I RSYM
TAD I0
TAD EQLS
SNA
JMP L8
CLA
TAD I0
TAD NM4
SMA
JMP I L5I
CLA
TAD FDGE
DCA I LT41I
TAD I0
TAD NM3
SNA
JMP I L5I
CLA
TAD FDGE
DCA I LT31I
TAD I0
TAD NM2
SNA
JMP I L5I
CLA
TAD FDGE
DCA I LT21I
JMP I L5I
L7,CLA
DCA Z0
L9,TAD I0
TAD A
TAD LENGTH
DCA J
TAD I J
DCA X
TAD X
SZA
JMP L10
JMS I MSGE
215
212
314  /L
305  /E
316  /N
307  /G
324  /T
310  /H
240
277  /?
0
JMP I L5I
L10,JMS I RSYM
TAD I0
TAD FSTP
SZA
JMP L11
JMS I RSYM
TAD I0
TAD FSTP
SZA
JMP L12
TAD X
CLL RAL
TAD X
CLL RAL
TAD X
CLL RAR
CLL RAR
DCA X
JMS I RSYM
JMP L11
L12,CLA
TAD X
CLL RAL
TAD X
CLL RAR
DCA X
L11,CLA
TAD X
TAD Z0
DCA Z0
TAD I0
TAD T
SZA
JMP L13
JMS I RSYM
JMP L9
L13,CLA
TAD I0
TAD EQLS
SZA
JMP I L14I
JMS I RSYM
TAD I0
TAD N9P1
SMA
JMP LA2
CLA
TAD I0
TAD N0
SMA
JMP LA3
LA2,JMS I MSGE
215
212
323  /S
320  /P
305  /E
305  /E
304  /D
240
277  /?
0
JMP I L5I
LA3,DCA X
LA5,JMS I RSYM
TAD I0
TAD N9P1
SMA
JMP I LA4I
CLA
TAD I0
TAD N0












































































*600

SPA
JMP LA4
DCA I0
TAD X
CLL RAL
DCA X
TAD X
CLL RAL
CLL RAL
TAD X
TAD I0
DCA X
JMP I LA5I
LA4,CLA
TAD Z0
DCA W1
TAD X
DCA W2
JMS I MULT
DCA Y
TAD W4
SZA
JMP LA6
TAD Y
RAL
SNL
JMP I L15I
LA6,JMS I MSGE
215
212
324  /T
317  /O
317  /O
240
306  /F
301  /A
323  /S
324  /T
240
241  /!
0
JMP I L0I
L14,CLA
TAD I0
TAD LBKT
SZA
JMP L16
IAC
DCA CHORD
JMS I RSYM
L16,CLA
TAD I0
TAD GP1
SMA
JMP LA8
CLA
TAD I0
TAD A
SMA
JMP L17
JMP LA9
LA8,CLA
TAD I0
TAD R
SNA
JMP LA14
LA9,JMS I MSGE
215
212
316  /N
317  /O
324  /T
305  /E
240
277  /?
0
LA14,JMS I RSYM
JMP I L18I
L17,DCA I0
TAD I0
TAD NOTE
DCA N
TAD I N
DCA N
TAD I0
TAD KEY
DCA J
TAD I J
DCA J
JMS I RSYM
TAD I0
TAD SHRP
SNA
JMP L20
CLA
TAD I0
TAD FLT
SZA
JMP L22
CMA
TAD N
DCA N
JMP L23
L20,ISZ N
L23,JMS I RSYM
TAD I0
TAD SHRP
SNA
JMP L24
CLA
TAD I0
TAD FLT
SZA
JMP I L26I
CMA
TAD N
DCA N
JMP L27
L24,ISZ N
L27,JMS I RSYM
JMP I L28I
L22,CLA
TAD I0
TAD NTRL
SNA
JMP I L29I
CLA
TAD N


























































































*1000

TAD J
DCA N
JMP L28
L29,JMS I RSYM
L26,CLA
TAD I0
TAD NTRL
SNA
JMP L29
L28,CLA
TAD I0
TAD PLUS
SNA
JMP L30
CLA
TAD I0
TAD MINUS
SZA
JMP L32
TAD N
TAD NM12
DCA N
JMP L33
L30,TAD NM12
CIA
TAD N
DCA N
L33,JMS I RSYM
JMP L28
L32,CLA
TAD N
SPA
JMP LA10
TAD NM61
SPA
JMP L34
LA10,JMS I MSGE
215
212
322  /R
301  /A
316  /N
307  /G
305  /E
240
241  /!
0
L18,CLA
TAD CLOCK
DCA CLCK
DCA N
L34,CLA CLL
TAD Z0
RAL
TAD Z0
RAL
TAD Z0
RAL
TAD Z0
RTL
DCA W1
TAD N
TAD F
DCA J
TAD I J
DCA W2
JMS I MULT
DCA V2
TAD W4
DCA V1
TAD Y
JMS I DIVIDE
SNL
JMP LA11
JMS I MSGE
215
212
324  /T
317  /0
317  /0
240
314  /L
317  /0
316  /N
307  /G
240
241  /!
0
JMP LA7
LA11,TAD V2
CIA
DCA I K
TAD NM13
CIA
DCA V1
TAD NUM
DCA V2
TAD I J
JMS I DIVIDE
TAD V2
CIA
DCA I K
TAD CLCK
DCA I K
TAD CLICK
DCA CLCK
CLL
TAD K
TAD MAX
SNL
JMP LA7
JMS I MSGE
215
212
324  /T
317  /O
317  /O
240
315  /M
325  /U
303  /C
310  /H
240
241  /!
0
JMP I L4I
NOP
LA7,CLA











































































*1200

L19,TAD I0
TAD RBKT
SNA CLA
DCA CHORD
TAD CHORD
SNA CLA
JMP I L1I
TAD I0
TAD ZP1
SMA CLA
JMP LA12
TAD I0
TAD A
SMA
JMP I L16I
LA12,JMS I RSYM
JMP L19
L4,CLA
DCA I K
DCA I K
LT0,CLA
TAD K1
DCA K
LA16,CMA
DCA U1
CMA
DCA U2
CMA
DCA U3
CMA
DCA U4
CMA
DCA V1
CMA
DCA V2
CMA
DCA V3
CMA
DCA V4
LT11,ISZ U1
JMP LT21
C1,CLICK
ISZ V1
JMP LT12
TAD I K
SNA
JMP LA15
DCA V1
TAD I K
DCA W1
TAD I K
DCA C1
LT12,TAD W1
DCA U1
LT21,ISZ U2
JMP LT31
C2,CLICK
ISZ V2
JMP LT22
TAD I K
SNA
JMP LA15
DCA V2
TAD I K
DCA W2
TAD I K
DCA C2
LT22,TAD W2
DCA U2
LT31,ISZ U3
JMP LT41
C3,CLICK
ISZ V3
JMP LT32
TAD I K
SNA
JMP LA15
DCA V3
TAD I K
DCA W3
TAD I K
DCA C3
LT32,TAD W3
DCA U3
LT41,ISZ U4
JMP LT11
C4,CLICK
ISZ V4
JMP LT42
TAD I K
SNA
JMP LA15
DCA V4
TAD I K
DCA W4
TAD I K
DCA C4
LT42,TAD W4
DCA U4
JMP LT11
LA15,TAD I K
SZA CLA
JMP LA16
JMP I L0I
RSYM1,0
LR1,RSF
JMP LR1
CLA
RRB
RFC
AND B177
SNA
JMP LR1
DCA I0
TAD I0
TAD SP
SNA CLA
JMP LR1
TAD I0
TAD CR
SNA CLA
JMP LR1
TAD I0
TAD RBT
SNA CLA
JMP LR1
JMP I RSYM1






















































































*1400

PSMBL1,0
TSF
JMP .-1
TLS
JMP I PSMBL1
MSGE1,0
LM1,CLA
TAD I MSGE1
ISZ MSGE1
SNA
JMP I MSGE1
JMS I PSMBL
JMP LM1
MULT1,0
CLA CLL
DCA W4
TAD NM12
DCA W3
LOOP,TAD W1
RAR
DCA W1
TAD W4
SNL
JMP .+3
CLL
TAD W2
RAR
DCA W4
ISZ W3
JMP LOOP
TAD W1
RAR
JMP I MULT1
DIV1,0
CIA
DCA V3
CLL
TAD V3
TAD V1
SZL
JMP I DIV1
CLA
TAD NM13
DCA V4
JMP DV2
DV3,TAD V1
RAL
DCA V1
TAD V1
TAD V3
SZL
DCA V1
CLA
DV2,TAD V2
RAL
DCA V2
ISZ V4
JMP DV3
JMP I DIV1











































































































*1500

DECIMAL

48
51
54
57
60
64
68
72
76
81
85
91
96
102
108
114
121
128
136
144
152
161
171
181
192
203
215
228
242
256
271
287
304
323
342
362
384
406
431
456
483
512
542
575
609
645
683
724
767
813
861
912
967
1024
1085
1149
1218
1290
1367
1448
1534













































































































$